home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / umich / falcon / programm.ing / nt_dsp1.lzh / NT_DSP1.MSA / LFLTS / LATNRM.ASM < prev    next >
Assembly Source File  |  1989-01-24  |  1KB  |  42 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; Normalized Lattice IIR Filter Macro.
  7. ; 
  8. ; Last Update 01 Aug 86   Version 1.0
  9. ;
  10. latnrm  macro   order
  11. latnrm  ident   1,0
  12. ;
  13. ;       Normalized Lattice filter macro
  14. ;
  15. ;       Input value in register y0, output value in register A
  16. ;
  17. ;       Macro call:
  18. ;               latnrm  order           ;call macro
  19. ;
  20. ;       where 'order' is the number of reflections coefficients
  21. ;       in the filter.
  22. ;
  23. ;       Alters registers: x0 x1 y0 y1 a b, r0 r4, pc sr
  24. ;
  25. ;       Uses 2 locations on stack
  26. ;
  27. ;
  28.   move           x:(r0)+,x1               ;get first Q in table
  29.   do    #order,_endnlat
  30.   mpy   x1,y0,a  x:(r0)+,x0   y:(r4),y1   ;q*w, get k, get s
  31.   macr -x0,y1,a  b,y:(r4)+                ;a-k*s, save new s
  32.   mpy   x0,y0,b               a,y0        ;k*w, set new w
  33.   macr  x1,y1,b  x:(r0)+,x1               ;b+q*s, get next q
  34. _endnlat              
  35.   move                        b,y:(r4)+   ;sv scnd lst st
  36.   move                        a,y:(r4)+   ;save last state
  37.   clr   a                     y:(r4)+,y0  ;clr acc, get fst st
  38.   rep   #order                            ;do fir taps
  39.   mac   x1,y0,a  x:(r0)+,x1   y:(r4)+,y0
  40.   macr  x1,y0,a               (r4)+       ;lst tap, rnd, adj pointer
  41.   endm
  42.